单片机 汇编程序 串口通信

Question

使用计算机串口发送软件向单片机发送 hello。当单片机接收到后向计算机返回 OK作为回复，用汇编语言编写

Answer 1

HERE: AJMP HERE
SINT: MOV P1,R0
JB RI,RECV
JB TI,SEND
AJMP HERE

中断里面直接用这种方式直接跳到主程序，我以前还是真没试过，不过估计能行吧。 我一直用RETI 返回堆栈地址位置的。

但下面这地方肯定有错的，就是执行MOV SBUF,A 后没有等待！！
正确的顺序是： CLR TI ;清发送标记
MOV SBUF,A ;发送
JNB TI,$ ; 这里是如果TI没有被置1就等待，因为送数可能还没有完成。。就去执行别的动作，可能会有问题。
接收也一样要等待:
MOV A,SBUF
JNB RI,$ ;等待接收完成标志。

另外：
CPL P1.7 有问题，我猜你是用P1.7来观察接收次数，
但由于CPL P1.7取反命令是读一下P1.7再取反输出的，如果你的p1.7外接电路不科学，不合理，可能会出现你每次不管发1,还是发0，p1.7都是低电平，比如你将p1.7直接接在npn三管基极就会一直是0V或0.7V ， P1.7的读入值会总为0，CPL 输出会总是为1
你可以用内部（非P口的位地址过度一下），比如： CPL 01H
MOV C，01H
MOV P1.7，C
你先试验吧。。。

Answer 2

;51 单片机的汇编语言程序：

ORG 0000H
JMP START
ORG 0023H
JB TI, S0_END
CLR RI
MOV A, 34H
MOV 34H, SBUF
MOV R0, #33H
S0_L:
XCH A, @R0
DEC R0
CJNE R0, #2FH, S0_L
SETB F0
S0_END:
RETI
START:
MOV SCON, #50H
MOV TMOD, #20H
MOV TH1, #0FDH
MOV TL1, #0FDH
SETB TR1
MOV IE, #90H
M_LOOP:
JNB F0, M_LOOP
CLR F0
MOV R1, #30H
CJNE @R1, #'h', M_LOOP
INC R1
CJNE @R1, #'e', M_LOOP
INC R1
CJNE @R1, #'l', M_LOOP
INC R1
CJNE @R1, #'l', M_LOOP
INC R1
CJNE @R1, #'o', M_LOOP
MOV SBUF, #'O'
JNB TI, $
CLR TI
MOV SBUF, #'K'
JNB TI, $
CLR TI
JMP M_LOOP
END本回答被提问者和网友采纳

Answer 3

FLAG BIT 00H
ORG 0000H
LJMP MAIN
ORG 0023H
LJMP UART
ORG 0030H
MAIN:
MOV TMOD,#20H
MOV TH1,#0FDH
MOV TL1,#0FDH
MOV SCON,#50H
SETB TR1
SETB ES
SETB EA
MOV R0,#30H
MOV R2,#0
CLR FLAG
LOOP:
JNB FLAG LOOP
MOV A,30H
CJNE A,#'h',RETRY
MOV A,31H
CJNE A,#"e',RETRY
MOV A,32H
CJNE A,#'l',RETRY
MOV A,33H
CJNE A,#'l',RETRY
MOV A,34H
CJNE A,#'o',RETRY
CLR TI
MOV SBUF,#'O'
JNB TI,$
CLR TI
MOV SBUF,#'K'
JNB TI,$
CLR TI
RETRY:
MOV R0,#30H
MOV R2,#0
CLR FLAG
LJMP LOOP
UART:
JB RI,RECIVE
RETI
RECIVE:
CLR RI
MOV A,SBUF
MOV @R0,A
INC R0
INC R2
CJNE R2,#5,UEND
SETB FLAG
UEND:
RETI
END